Thinkin' Science - 1st & 2nd Grades/Thinkin' Science - First and Second Grades (Edmark)(Version 1.0)(1997).ISO/pc/dearpar/dpdata/dp.dir/00068_Script_68

Text File | 1997-09-03 | 10KB | 328 lines

------------------------------------------------------
------------------- MAIN MOVIE SCRIPT --------------------

--This file was coded by Paul Katz using existing code supplied by Edmark.
--Date of this project:  August 21-25, 1997

--Paul Katz can be contacted via e-mail at:  [e-mail]

--Home telephone:  [phone]

--Web address:  http://www.mindspring.com/~paulkatz

--Notes:  Most of the code within this file is my own.  I have used similar routines to those I found in the earlier code, but have used different variable/handler names.  I took the "doSmackerVideo" handler directly from pre-existing code and made no significant changes.  A major difference between this file and earlier files is my use of cast member names to define the global variable gWhere, which is also the Frame Label Name of the appropriate video playback frame when a button has been clicked.  There are pop-up labels on the icon buttons which reside in channels 20 levels higher than their counterpart icon buttons.  A "buttonClick" handler deals with sorting out whether or not the user has clicked on the icon button or it's associated label, carries out the button click routine and sends the playback head to the appropriate video playback frame label.

-- Components/Xtras:  Smacker Xtra  Version 3.0 by RAD Game Tools
------------------------------------------------------
------------------------------------------------------


on ChangeColordepth

  global gBitDepthFlag, gBitDepth


  -- If this is a Mac,  then make sure the bitdepth is 8bit.  Transparent backgrounds
  --  will disapeer

  if the machineType <> 256 then

    -- Remember the depth, for setting back on quit.
    set gBitDepth to  the colorDepth

    -- Set the current display is not 8bit then set to 8bit
    if the colordepth <> 8 then
      set the colordepth to 8
      if the colorDepth = 8  then
        set gBitDepthFlag = TRUE
      else
        set gBitDepthFlag = FALSE
        alert "Please change your system to 256 colors and reboot."
      end if
    end if
  end if

end ChangeColordepth

------------------------


on startMovie
  global gLabelList, gMovie_Path, gReadingClicked, gTestQuit

  set gLabelList = ["dp_2":5,"dp_3":6,"dp_4":7,"dp_5":8,"dp_6":9,"dp_7":10,"dp_8":11,"dp_9":12,"dp_10":13,"dp_11":14]

  set gMovie_Path = (the moviePath)

  -- center the stage and set the mouse scripts
  set the centerStage to TRUE
  ChangeColordepth
  set the stageColor = 255

  set gReadingClicked = FALSE

  set gTestQuit = FALSE

  set the visible of sprite 15 to TRUE

  set the keyDownScript = "_testQuit"

  -- clearLabels

  setVisible 15,15, TRUE
  setVisible 16, 21, FALSE

  initSmacker

end

on clearLabels
  --  the following makes all icon button labels hidden.

  repeat with i = 25 to 34
    set the visible of sprite i to FALSE
  end repeat
end

on setVisible first, last, state
  repeat with i = first to last
    set the visible of sprite i to state
  end repeat
end

on buttonClick
  global gWhere, gLabelList, gwhichSprite
  if the clickOn = 0 then
    exit
  end if

  set the mouseDownScript to empty
  set the mouseUpScript to empty
  set baseName = the name of the member of sprite the clickOn

  set baseName = char 1 to (length(baseName) - 2) of baseName

  set gWhichSprite = the clickOn

  -- not needed for
  --  if the clickOn > 22 then
  --
  --    set gWhichSprite = getAProp(gLabelList,baseName)
  --
  --  end if

  set gWhere = baseName

  if the clickOn = 3 then
    puppetSound "Snap Shot"
  else
    puppetSound "button sound"
  end if

  set the memberNum of sprite gWhichSprite to the number of member (baseName &"_D")
  updateStage

  repeat while the StillDown = TRUE
    if rollOver(the clickOn) = TRUE then
      set the memberNum of sprite gWhichSprite to the number of member (baseName &"_D")
      updateStage
    else
      set the memberNum of sprite gWhichSprite to the number of member (baseName &"_U")
      updateStage
    end if
  end repeat
  set the memberNum of sprite gWhichSprite to the number of member (baseName &"_U")
  updatestage

  if rollOver(the clickOn) = TRUE then

    set the memberNum of sprite gWhichSprite to the number of member (baseName&"_S")
    updateStage
    -- set the mouseUpScript to "lockmouseUpScript"
    -- set the mouseDownScript to "lockmouseDownScript"
    if gWhere = "dp_1" then
      go to frame "dp_1"
    else if gWhere = "stop" then
      go to frame "stop"
    else
      set the mouseUpScript to "lockmouseUpScript"
      set the mouseDownScript to "lockmouseDownScript"
      go to frame "Play Video"
    end if
  end if
end

on lockmouseUpScript
  stopEvent
end

on lockmouseDownScript
  stopEvent
end

on setPuppets first, last, state
  repeat with i = first to last
    puppetSprite i, state
  end repeat
end

-- Function for playing all smacker videos and closing them
on DoSmackerVideo

  global gSmkObject, gMovie_Path, gWhere, gwhichSprite

  -- Play the smacker movie with one sound track and no preload.
  SmackOpen(gSmkObject,gMovie_Path &(gWhere)&".smk", 1, 0 )

  -- Get the total number of frames
  set gLastFrame = SmackGetFrames(gSmkObject)

  -- Make sure the movie stops if a "q", escape key, left or right
  -- mouse button, or loss of focus (this app is no longer up front), then stop movie
  SmackSetInterfaceKeys(gSmkObject, "q\e\m\r\f")


  -- The macintosh version plays smacker video off to the right by 2 pixals from the Windows version
  -- and plays better if Smacker is made to play a frame at a time.  So do framebyframe play for the Mac
  -- and play the whole movie at once for Windows and ajust for 2 pixals.

  -- If we are on a windows machine...
  if the machineType = 256 then
    -- set position for reading
    -- test for windows remap
    SmackRemapToSystemPalette(gSmkObject)
    -- set position for reading
    case gWhere of
      "dp_0","dp_12": SmackSetPosition(gSmkObject,203,132)
      Otherwise SmackSetPosition(gSmkObject,172,110)
    end case
    -- Play entire movie (it will autmatically break to interface keys & mouse events set earlier)
    SmackPlay(gSmkObject)

  else
    -- Make sure the palette remaps (The Macintosh Smacker Xtra will not use its own palette correctly so
    -- Have it remap to the current palette)
    SmackRemapToSystemPalette(gSmkObject)

    -- set position for reading
    case gWhere of
      "dp_0","dp_12": SmackSetPosition(gSmkObject,203,132)
      Otherwise SmackSetPosition(gSmkObject,172,110)
    end case

    -- Loop through every frame in the movie
    repeat with nFrame = 1 to gLastFrame
      SmackPlayFrames( gSmkObject, nFrame, nFrame )
      -- If there was a mouse or key event stop playing
      if (SmackGetLastKey(gSmkObject)) <> ""  then exit repeat
    end repeat

  end if


  -- Movie is now finished, close it so we get the sound channels back
  SmackClose(gSmkObject)

  if gWhere <> "dp_0" then
    set the memberNum of sprite gWhichSprite = the number of member (gWhere &"_U")
  end if
  updateStage

  -- Get the last event if there were any
  set sLastEvent = SmackGetLastKey(gSmkObject)

  -- If a mouse click or key stopped the movie then do mouseDown script for resetting.
  if (sLastEvent = "Q") or (sLastEvent = "\e") or (sLastEvent = "\m")¨
 or (sLastEvent = "\r") or (sLastEvent = "\f") then

    movieDoneCleanUp
    exit

  end if


end DoSmackerVideo

on initSmacker
  global gSmkObject

  -- Set paths for the appropriate smacker xtras
  if the platform = "Windows,16" then

    -- Load Smacker Xtra for 16bit windows (win 3.11)
    OpenXLib (the moviePath)& "smackx16"

  else if the platform = "Windows,32" then

    -- Load Smacker Xtra for 32bit windows (win95)
    OpenXLib (the moviePath) & "smackx32"

  else

    -- Load Smacker Xtra for any Macintosh
    OpenXLib (the moviePath) & "Smack Fat"

  end if

  -- Make a smacker controller object
  set gSmkObject=new(xtra "smacker")

end initSmacker

on _TestQuit
  global gTestQuit
  if (the key = "q") and (the commandDown) then

    -- If command & q was hit more than once then just get out
    if gTestQuit = True then Quit

    set gTestQuit = TRUE

    -- Set the cursor to a watch
    cursor 4
    go to frame "Stop"
  end if
end _TestQuit

on MovieStop_MouseDown
  --  global gWhichSprite, gWhere
  --
  --  -- Make sure events don't build up
  --  set the MouseDownScript = EMPTY
  --  set the MouseUpScript = EMPTY
  --
  --  updatestage
  --
  --  set gAutoplay = FALSE
  --
  --  -- If the mouse did not click on an active button exit
  --
  --  repeat with i = 4 to 21
  --
  --    if the clickOn <> i then
  --      movieDoneCleanUp
  --      dontPassEvent
  --      abort
  --    end if
  --  end repeat
  --
  --  pass
end MovieStop_MouseDown

on movieDoneCleanUp

  --      global gwhichSprite, gWhere
  --
  --      set the memberNum of sprite gWhichSprite = the number of member (gWhere &"_U")
  --      updateStage

end


on QuitMovie
  -- Clean up Smacker objects before quiting
  global gSmkObject

  smackClose gSmkObject

end QuitMovie